## Using MiServer to Provide RESTful Web Services

A MiSite can be configured to provide RESTful web services. This document describes the steps necessary to do so. While we will cover some RESTful concepts, this is not tutorial on RESTful web services themselves – for a good overview of RESTful web services, please see <http://www.drdobbs.com/web-development/restful-web-services-a-tutorial/240169069>.

### Web Service Technologies

A web service is a method of communication between two processes over a network. A web service does not have a GUI interface, though GUI interfaces to web services are common. For instance, a web page that prompts for a postal code may use a web service for validation, but it's the web page that provides the GUI, not the web service.

There are currently two predominant web service technologies – SOAP-based and REST. SOAP-based web services use XML-based protocols for message exchange. Dyalog provides support for SOAP-based web services with SAWS, the Stand Alone Web Services framework. REST (Representational State Transfer) web services have become popular for providing public APIs. REST is an architectural style, unlike SOAP which is a standardized protocol. REST makes use of HTTP, and does not create any new standards. It can structure data into XML, YAML, or any other machine readable format, but usually JSON – JavaScript Object Notation – is preferred. REST is very data-driven, compared to SOAP, which is strongly function-driven. A web service that uses REST is termed "RESTful".

### The 5 Minute Oversimplified Guide to REST

This section is intended to give you a very basic understanding of REST. REST implements a verb-noun style of interaction.

#### Verbs

The verbs in REST are the set of HTTP commands. If you're familiar with web site technology, you probably already know about the HTTP commands **GET** and **POST**. The HTTP protocol has several other commands that are often used for RESTful web services. The first four verbs are typically used to implement CRUD – the operations CREATE, READ, UPDATE, and DELETE.

|  |  |
| --- | --- |
| **Verb (HTTP Command)** | **Common RESTful Use** |
| **GET** | READ – retrieve a resource |
| **POST** | UPDATE – update an existing resource |
| **PUT** | CREATE – create a new resource |
| **DELETE** | DELETE – delete a resource |
| **HEAD** | check if a resource exists |
| **OPTIONS** | query what verbs are available for a resource |

#### Nouns

The nouns in REST are resources and are accessed via URIs (Uniform Resource Identifiers).

A resource is some collection of data. It could be a list of customers, information about a specific customer, a list of orders for a specific customer, the order details for a specific order for a specific customer,... you get the idea.

A URI is simply a string of characters to identify a resource. You're probably most familiar with URLs, which is a type of URI that identifies a web address - typically a file somewhere on the web. A URI doesn't necessarily have to point to an actual physical resource like a file, it merely identifies it. For instance, the URI <http://someWebService.com/customer/123> might identify the customer with id 123 though there may not be an actual file for customer 123.

### A Few Observations

* REST is very flexible and you have the power to implement (or not) whatever set of verbs upon   
  whatever resources make sense for your application. For instance:  
  **POST** <http://myservice/Persons/> might add a new record to the Persons table in your application, but  
  **POST** <http://myservice/> may not make any sense in the context of your application.
* REST is inherently stateless which means that each request is independent. This can pose some design challenges.
* REST itself does not address issues of authentication – these are typically handled by HTTP or some external authentication mechanism. MiServer and REST

### Configuration

In your MiSite configuration folder, create or update the following entries in Server.xml.

* Set RESTful to 1 – this is important so that MiServer knows how to interpret URIs.   
  For example, the URI <http://myservice/Persons/Brian>   
  RESTful≠1 – look for the file /Persons/Brian

RESTful=1 – look for the file /Persons and supply "Brian" as a parameter

* Set AllowedHttpCommands to a comma-delimited string of the verb you wish to support in your web service.

<Server>  
 <RESTful>1</RESTful>  
 <AllowedHttpCommands>get,put,delete,post</AllowedHttpCommands>  
</Server>

**It is strongly recommended that you update /Config/Server.xml file in your MiSite folder and not at the MiServer level.**

### RESTful Page Requirements

#### Use the RESTful base class for your pages

Instead of using **MiPage**, or some other base class, you will use **RESTful** as the base class for your RESTful pages.

:Class myService : **RESTful**    
:EndClass

#### Use Respond instead of Compose

MiServer expects a public method named **Respond** to return the results for your web service.   
**Respond** must be niladic and return a result.

∇ r←Respond  
 :Access public  
 ⍝ your code here  
 ∇

### Features of the RESTful Base Class

The RESTful base class shares many features of the MiPage class.

* data passed with the HTTP request, either via query parameters in the URI, or in the message body are stored in \_PageData and are accessible with the GET method.
* \_Command returns the lowercased HTTP command
* \_URI returns a vector of vectors containing the segments of the URI  
  e.g. for the URI /customer/123/order, \_URI will contain

\_URI

┌────────┬───┬─────┐

│customer│123│Order│

└────────┴───┴─────┘  
Note: the first element is the name of the your RESTful page.

* SetStatus will set the HTTP status code (for more detail about HTTP status codes than you'll ever want to see look at: <http://www.w3.org/Protocols/rfc2616/rfc2616-sec10.html> ).  
  Note: Status 200 (OK) is set by default, you only need to set the status when something goes wrong, like a resource not being found (status 404).
* SetHeader is used to set HTTP headers in the response.  
  MiServer takes care of setting most headers like content-length and content-type for you.

### Examples

#### Simple Read Only Loan Calculation Service

The page below implements a loan calculation web service.  
The parameters are provided in the query string of the URI.  
The results are stored in a namespace, which MiServer converts into a JSON object.   
  
:Class mortgagews : RESTful   
⍝ calculate payment   
 calcpmt←{0::'Error' ⋄ p r n←⍵÷1 1200 (÷12) ⋄ .01×⌈100×p×r÷1-(1+r)\*-n}  
⍝ calculate principle  
 calcprin←{0::'Error' ⋄ r n m←⍵÷1200 (÷12) 1 ⋄ .01×⌈100×m÷r÷1-(1+r)\*-n}  
  
 ∇ response←Respond;mask;r ⍝ render the initial page  
 :Access Public   
 r←⎕NS ''  
 r.msg←'Please provide either (prin rate term) or (rate term pmt)'  
 :if 1=+/mask←⍬∘≡¨r.(prin rate term pmt)←⍬ Get 'prin rate term pmt'  
 :if mask[1] ⍝ principle missing  
 r.(msg prin)←'' (calcprin r.(rate term pmt))  
 :elseif mask[4] ⍝ payment missing  
 r.(msg pmt)←'' (calcpmt r.(prin rate term))  
 :endif  
 :endif  
 response←1 #.JSON.fromAPL r  
 ∇  
:EndClass

Request: <http://localhost:8080/mortgagews?prin=100000&rate=.05&term=30>

Response: {msg:"",pmt:279.88,prin:100000,rate:0.05,term:30}

#### More Comprehensive Web Service

:Class customer : RESTful  
 ∇ r←Respond;custid;urlParams  
 :Access public  
 r←''  
   
 :Select \_Command ⍝ which HTTP command?  
 :Case 'post' ⍝ create new customer  
 r←AddCustomer  
 :Case 'get' ⍝ retrieve  
 r←GetCustomer  
 :Case 'put' ⍝ update  
 r←UpdateCustomer  
 :Case 'delete' ⍝ delete  
 r←DeleteCustomer  
 :Case 'options' ⍝ documentation  
 r←Documentation  
 :Else ⍝ invalid command  
 SetStatus 400 ⍝ Bad Request  
 →0  
 :EndSelect  
   
 :If 0∊⍴r  
 SetStatus 404 ⍝ Not Found  
 :EndIf  
 ∇

∇ r←AddCustomer;name

:Access public

r←⍬

:If ~0∊⍴name←Get'name' ⍝ was a name supplied?

:AndIf 0∊⍴\_URI ⍝ make sure no addition URI information

r←'custid' 'custname'Annotate #.bl.AddCustomer name

:Else

SetStatus 400 'Invalid format'

:EndIf

∇

∇ r←GetCustomer

:Select ⊃⍴\_URI

:CaseList 0 1

:If ~0∊⍴r←#.bl.GetCustomer \_URI

r←'custid' 'custname' 'custURI'Annotate r,makeCustomerURI¨r[;1]

:EndIf

:CaseList 2 3 ⍝ GET customer/custid/order or customer/custid/order/orderid

:If 'order'≡2⊃\_URI

:If ~0∊⍴r←#.bl.GetCustomerOrders 1⊃\_URI

:If 2=⍴\_URI ⍝ retrieve list of orders for customer

r←'orderid' 'custid' 'orderdate'Annotate r

:ElseIf ~0∊⍴r←(1⊃\_URI)#.bl.getCustomerOrder(3⊃\_URI)

r←'order' 'details'#.JSON.toNS('orderid' 'custid' 'orderdate')('qty' 'productid' 'productname')Annotate¨r

:EndIf

:EndIf

:Else

SetStatus 400 'Invalid format'

:EndIf

:EndSelect

∇

∇ r←UpdateCustomer;name

r←⍬

:If ~0∊⍴name←Get'name' ⍝ was a name supplied?

:AndIf 1=⍴\_URI ⍝ make sure id was passed in URL

r←'custid' 'custname'Annotate(1⊃\_URI)#.bl.UpdateCustomer name

:EndIf

∇

∇ r←DeleteCustomer

r←⍬

:If 1=⍴\_URI ⍝ make sure id was passed in URL

:AndIf 0∊⍴GetNames'' ⍝ and nothing in the query string

r←#.bl.DeleteCustomer 1⊃\_URI

r←'custinfo' 'orders' 'details'#.JSON.toNS('custid' 'custname')('orderid' 'custid' 'orderdate')('orderid' 'qty' 'productid' 'productname')Annotate¨r

:EndIf

∇

∇ r←Documentation

SetContentType'txt'

r←ScriptFollows~⎕UCS 10

⍝ The following operations are supported for /customer

⍝ GET

⍝ /customer/ list of all customers

⍝ /customer/custid/ information on a specific customer

⍝ /customer/custid/order/ information about a specific customer's orders

⍝ /customer/custid/order/orderid/ details for a specific order for a specific customer

⍝

⍝ POST

⍝ /customer/ create a new customer

⍝ form variable: name

⍝

⍝ PUT

⍝ /customer/custid update customer information for a specific customer

⍝ form variable: name

⍝

⍝ DELETE

⍝ /customer/custid delete a specific customer

⍝

⍝ OPTIONS

⍝ /customer/ return this documentation

∇

⍝---------------------------⍝

⍝ Constructor and Utilities ⍝

⍝---------------------------⍝

∇ make;config

⍝ This is called when an instance of this page is first created

⍝ It performs some basic setup for demonstration purposes

:Implements constructor

:Access public

:Trap 6

config←#.Boot.ms.Config

:If 0=config.⎕NC'Address' ⋄ Address←'localhost:',⍕config.Port

:Else ⋄ Address←config.Address

:EndIf

:Else

Address←''

:EndTrap

∇

makeURI←{'http://',Address,'/',⍺,'/',(⍕⍵),'/'}

makeCustomerURI←'Customer'∘makeURI

makeOrderURI←'Order'∘makeURI

makeProductURI←'Product'∘makeURI

Annotate←{0∊⍴⍵:⍵ ⋄ ⍺ #.JSON.fromTable toMat ⍵}

toMat←{{⍵{((×/¯1↓⍵),¯1↑⍵)⍴⍺}⍴⍵}eis ⍵}

:EndClass